home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / hexl.el.z / hexl.el
Encoding:
Text File  |  1998-10-28  |  28.0 KB  |  790 lines
  1. ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
  2.  
  3. ;; Copyright (C) 1989, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
  6. ;; Maintainer: FSF
  7. ;; Keywords: data
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24. ;; Boston, MA 02111-1307, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;; This package implements a major mode for editing binary files.  It uses
  29. ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30. ;; can filter a binary into an editable format or from the format back into
  31. ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32. ;; do `M-x describe-mode'.
  33. ;;
  34. ;; This may be useful in your .emacs:
  35. ;;
  36. ;;    (autoload 'hexl-find-file "hexl"
  37. ;;      "Edit file FILENAME in hexl-mode." t)
  38. ;;    
  39. ;;    (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40. ;;
  41. ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42. ;;
  43. ;; Currently hexl only supports big endian hex output with 16 bit
  44. ;; grouping.
  45. ;;
  46. ;; -iso in `hexl-options' will allow iso characters to display in the
  47. ;; ASCII region of the screen (if your emacs supports this) instead of
  48. ;; changing them to dots.
  49.  
  50. ;;; Code:
  51.  
  52. ;;
  53. ;; vars here
  54. ;;
  55.  
  56. (defvar hexl-program "hexl"
  57.   "The program that will hexlify and dehexlify its stdin.
  58. `hexl-program' will always be concatenated with `hexl-options'
  59. and \"-de\" when dehexlifying a buffer.")
  60.  
  61. (defvar hexl-iso ""
  62.   "If your emacs can handle ISO characters, this should be set to
  63. \"-iso\" otherwise it should be \"\".")
  64.  
  65. (defvar hexl-options (format "-hex %s" hexl-iso)
  66.   "Options to hexl-program that suit your needs.")
  67.  
  68. (defvar hexlify-command
  69.   (format "%s%s %s" exec-directory hexl-program hexl-options)
  70.   "The command to use to hexlify a buffer.")
  71.  
  72. (defvar dehexlify-command
  73.   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  74.   "The command to use to unhexlify a buffer.")
  75.  
  76. (defvar hexl-max-address 0
  77.   "Maximum offset into hexl buffer.")
  78.  
  79. (defvar hexl-mode-map nil)
  80.  
  81. (defvar hexl-mode-old-local-map)
  82. (defvar hexl-mode-old-mode-name)
  83. (defvar hexl-mode-old-major-mode)
  84. (defvar hexl-mode-old-write-contents-hooks)
  85. (defvar hexl-mode-old-require-final-newline)
  86. (defvar hexl-mode-old-syntax-table)
  87.  
  88. ;; routines
  89.  
  90. ;;;###autoload
  91. (defun hexl-mode (&optional arg)
  92.   "\\<hexl-mode-map>
  93. A major mode for editing binary files in hex dump format.
  94.  
  95. This function automatically converts a buffer into the hexl format
  96. using the function `hexlify-buffer'.
  97.  
  98. Each line in the buffer has an \"address\" (displayed in hexadecimal)
  99. representing the offset into the file that the characters on this line
  100. are at and 16 characters from the file (displayed as hexadecimal
  101. values grouped every 16 bits) and as their ASCII values.
  102.  
  103. If any of the characters (displayed as ASCII characters) are
  104. unprintable (control or meta characters) they will be replaced as
  105. periods.
  106.  
  107. If `hexl-mode' is invoked with an argument the buffer is assumed to be
  108. in hexl format.
  109.  
  110. A sample format:
  111.  
  112.   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
  113.   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
  114.   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
  115.   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
  116.   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
  117.   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
  118.   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
  119.   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
  120.   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
  121.   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
  122.   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are 
  123.   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
  124.   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
  125.   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character 
  126.   000000c0: 7265 6769 6f6e 2e0a                      region..
  127.  
  128. Movement is as simple as movement in a normal emacs text buffer.  Most
  129. cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
  130. to move the cursor left, right, down, and up).
  131.  
  132. Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
  133. also supported.
  134.  
  135. There are several ways to change text in hexl mode:
  136.  
  137. ASCII characters (character between space (0x20) and tilde (0x7E)) are
  138. bound to self-insert so you can simply type the character and it will
  139. insert itself (actually overstrike) into the buffer.
  140.  
  141. \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
  142. it isn't bound to self-insert.  An octal number can be supplied in place
  143. of another key to insert the octal number's ASCII representation.
  144.  
  145. \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
  146. into the buffer at the current point.
  147.  
  148. \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
  149. into the buffer at the current point.
  150.  
  151. \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
  152. into the buffer at the current point.
  153.  
  154. \\[hexl-mode-exit] will exit hexl-mode.
  155.  
  156. Note: saving the file with any of the usual Emacs commands
  157. will actually convert it back to binary format while saving.
  158.  
  159. You can use \\[hexl-find-file] to visit a file in hexl-mode.
  160.  
  161. \\[describe-bindings] for advanced commands."
  162.   (interactive "p")
  163.   (if (eq major-mode 'hexl-mode)
  164.       (error "You are already in hexl mode")
  165.  
  166.     (let ((modified (buffer-modified-p))
  167.       (inhibit-read-only t)
  168.       (original-point (1- (point)))
  169.       max-address)
  170.       (and (eobp) (not (bobp))
  171.        (setq original-point (1- original-point)))
  172.       (if (not (or (eq arg 1) (not arg)))
  173.       ;; if no argument then we guess at hexl-max-address
  174.           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
  175.         (setq max-address (1- (buffer-size)))
  176.         (hexlify-buffer)
  177.         (set-buffer-modified-p modified))
  178.       (make-local-variable 'hexl-max-address)
  179.       (setq hexl-max-address max-address)
  180.       (hexl-goto-address original-point))
  181.  
  182.     ;; We do not turn off the old major mode; instead we just
  183.     ;; override most of it.  That way, we can restore it perfectly.
  184.     (make-local-variable 'hexl-mode-old-local-map)
  185.     (setq hexl-mode-old-local-map (current-local-map))
  186.     (use-local-map hexl-mode-map)
  187.  
  188.     (make-local-variable 'hexl-mode-old-mode-name)
  189.     (setq hexl-mode-old-mode-name mode-name)
  190.     (setq mode-name "Hexl")
  191.  
  192.     (make-local-variable 'hexl-mode-old-major-mode)
  193.     (setq hexl-mode-old-major-mode major-mode)
  194.     (setq major-mode 'hexl-mode)
  195.  
  196.     (make-local-variable 'hexl-mode-old-syntax-table)
  197.     (setq hexl-mode-old-syntax-table (syntax-table))
  198.     (set-syntax-table (standard-syntax-table))
  199.  
  200.     (make-local-variable 'hexl-mode-old-write-contents-hooks)
  201.     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
  202.     (make-local-variable 'write-contents-hooks)
  203.     (add-hook 'write-contents-hooks 'hexl-save-buffer)
  204.  
  205.     (make-local-variable 'hexl-mode-old-require-final-newline)
  206.     (setq hexl-mode-old-require-final-newline require-final-newline)
  207.     (make-local-variable 'require-final-newline)
  208.     (setq require-final-newline nil)
  209.  
  210.     ;; Add hooks to rehexlify or dehexlify on various events.
  211.     (make-local-hook 'after-revert-hook)
  212.     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
  213.  
  214.     (make-local-hook 'change-major-mode-hook)
  215.     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t))
  216.   (run-hooks 'hexl-mode-hook))
  217.  
  218. (defun hexl-after-revert-hook ()
  219.   (hexlify-buffer)
  220.   (set-buffer-modified-p nil))
  221.  
  222. (defvar hexl-in-save-buffer nil)
  223.  
  224. (defun hexl-save-buffer ()
  225.   "Save a hexl format buffer as binary in visited file if modified."
  226.   (interactive)
  227.   (if hexl-in-save-buffer nil
  228.     (set-buffer-modified-p (if (buffer-modified-p)
  229.                    (save-excursion
  230.                  (let ((buf (generate-new-buffer " hexl"))
  231.                        (name (buffer-name))
  232.                        (file-name (buffer-file-name))
  233.                        (start (point-min))
  234.                        (end (point-max))
  235.                        modified)
  236.                    (set-buffer buf)
  237.                    (insert-buffer-substring name start end)
  238.                    (set-buffer name)
  239.                    (dehexlify-buffer)
  240.                    ;; Prevent infinite recursion.
  241.                    (let ((hexl-in-save-buffer t)
  242.                      (buffer-file-type t)) ; for ms-dos
  243.                      (save-buffer))
  244.                    (setq modified (buffer-modified-p))
  245.                    (delete-region (point-min) (point-max))
  246.                    (insert-buffer-substring buf start end)
  247.                    (kill-buffer buf)
  248.                    modified))
  249.                  (message "(No changes need to be saved)")
  250.                  nil))
  251.     ;; Return t to indicate we have saved t
  252.     t))
  253.  
  254. ;;;###autoload
  255. (defun hexl-find-file (filename)
  256.   "Edit file FILENAME in hexl-mode.
  257. Switch to a buffer visiting file FILENAME, creating one in none exists."
  258.   (interactive "fFilename: ")
  259.   (if (or (eq system-type 'ms-dos) (eq system-type 'windows-nt))
  260.       (find-file-binary filename)
  261.     (find-file filename))
  262.   (if (not (eq major-mode 'hexl-mode))
  263.       (hexl-mode)))
  264.  
  265. (defun hexl-mode-exit (&optional arg)
  266.   "Exit Hexl mode, returning to previous mode.
  267. With arg, don't unhexlify buffer."
  268.   (interactive "p")
  269.   (if (or (eq arg 1) (not arg))
  270.       (let ((modified (buffer-modified-p))
  271.         (inhibit-read-only t)
  272.         (original-point (1+ (hexl-current-address))))
  273.     (dehexlify-buffer)
  274.     (remove-hook 'write-contents-hooks 'hexl-save-buffer)
  275.     (set-buffer-modified-p modified)
  276.     (goto-char original-point)))
  277.  
  278.   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
  279.   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
  280.  
  281.   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
  282.   (setq require-final-newline hexl-mode-old-require-final-newline)
  283.   (setq mode-name hexl-mode-old-mode-name)
  284.   (use-local-map hexl-mode-old-local-map)
  285.   (set-syntax-table hexl-mode-old-syntax-table)
  286.   (setq major-mode hexl-mode-old-major-mode)
  287.   (force-mode-line-update))
  288.  
  289. (defun hexl-maybe-dehexlify-buffer ()
  290.   "Convert a hexl format buffer to binary.
  291. Ask the user for confirmation."
  292.   (if (y-or-n-p "Convert contents back to binary format? ")
  293.       (let ((modified (buffer-modified-p))
  294.         (inhibit-read-only t)
  295.         (original-point (1+ (hexl-current-address))))
  296.     (dehexlify-buffer)
  297.     (remove-hook 'write-contents-hooks 'hexl-save-buffer)
  298.     (set-buffer-modified-p modified)
  299.     (goto-char original-point))))
  300.  
  301. (defun hexl-current-address (&optional validate)
  302.   "Return current hexl-address."
  303.   (interactive)
  304.   (let ((current-column (- (% (point) 68) 11)) 
  305.     (hexl-address 0))
  306.     (if (< current-column 0)
  307.     (if validate
  308.         (error "Point is not on a character in the file")
  309.       (setq current-column 0)))
  310.     (setq hexl-address
  311.       (+ (* (/ (point) 68) 16)
  312.          (if (>= current-column 41)
  313.          (- current-column 41)
  314.            (/ (- current-column  (/ current-column 5)) 2))))
  315.     hexl-address))
  316.  
  317. (defun hexl-address-to-marker (address)
  318.   "Return marker for ADDRESS."
  319.   (interactive "nAddress: ")
  320.   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
  321.  
  322. (defun hexl-goto-address (address)
  323.   "Goto hexl-mode (decimal) address ADDRESS.
  324. Signal error if ADDRESS out of range."
  325.   (interactive "nAddress: ")
  326.   (if (or (< address 0) (> address hexl-max-address))
  327.       (error "Out of hexl region."))
  328.   (goto-char (hexl-address-to-marker address)))
  329.  
  330. (defun hexl-goto-hex-address (hex-address)
  331.   "Go to hexl-mode address (hex string) HEX-ADDRESS.
  332. Signal error if HEX-ADDRESS is out of range."
  333.   (interactive "sHex Address: ")
  334.   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
  335.  
  336. (defun hexl-hex-string-to-integer (hex-string)
  337.   "Return decimal integer for HEX-STRING."
  338.   (interactive "sHex number: ")
  339.   (let ((hex-num 0))
  340.     (while (not (equal hex-string ""))
  341.       (setq hex-num (+ (* hex-num 16)
  342.                (hexl-hex-char-to-integer (string-to-char hex-string))))
  343.       (setq hex-string (substring hex-string 1)))
  344.     hex-num))
  345.  
  346. (defun hexl-octal-string-to-integer (octal-string)
  347.   "Return decimal integer for OCTAL-STRING."
  348.   (interactive "sOctal number: ")
  349.   (let ((oct-num 0))
  350.     (while (not (equal octal-string ""))
  351.       (setq oct-num (+ (* oct-num 8)
  352.                (hexl-oct-char-to-integer
  353.             (string-to-char octal-string))))
  354.       (setq octal-string (substring octal-string 1)))
  355.     oct-num))
  356.  
  357. ;; move point functions
  358.  
  359. (defun hexl-backward-char (arg)
  360.   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
  361.   (interactive "p")
  362.   (hexl-goto-address (- (hexl-current-address) arg)))
  363.  
  364. (defun hexl-forward-char (arg)
  365.   "Move right ARG bytes (left if ARG negative) in hexl-mode."
  366.   (interactive "p")
  367.   (hexl-goto-address (+ (hexl-current-address) arg)))
  368.  
  369. (defun hexl-backward-short (arg)
  370.   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
  371.   (interactive "p")
  372.   (hexl-goto-address (let ((address (hexl-current-address)))
  373.                (if (< arg 0)
  374.                (progn
  375.                  (setq arg (- arg))
  376.                  (while (> arg 0)
  377.                    (if (not (equal address (logior address 3)))
  378.                    (if (> address hexl-max-address)
  379.                        (progn
  380.                      (message "End of buffer.")
  381.                      (setq address hexl-max-address))
  382.                      (setq address (logior address 3)))
  383.                  (if (> address hexl-max-address)
  384.                      (progn
  385.                        (message "End of buffer.")
  386.                        (setq address hexl-max-address))
  387.                    (setq address (+ address 4))))
  388.                    (setq arg (1- arg)))
  389.                  (if (> address hexl-max-address)
  390.                  (progn
  391.                    (message "End of buffer.")
  392.                    (setq address hexl-max-address))
  393.                    (setq address (logior address 3))))
  394.              (while (> arg 0)
  395.                (if (not (equal address (logand address -4)))
  396.                    (setq address (logand address -4))
  397.                  (if (not (equal address 0))
  398.                  (setq address (- address 4))
  399.                    (message "Beginning of buffer.")))
  400.                (setq arg (1- arg))))
  401.                address)))
  402.  
  403. (defun hexl-forward-short (arg)
  404.   "Move right ARG shorts (left if ARG negative) in hexl-mode."
  405.   (interactive "p")
  406.   (hexl-backward-short (- arg)))
  407.  
  408. (defun hexl-backward-word (arg)
  409.   "Move to left ARG words (right if ARG negative) in hexl-mode."
  410.   (interactive "p")
  411.   (hexl-goto-address (let ((address (hexl-current-address)))
  412.                (if (< arg 0)
  413.                (progn
  414.                  (setq arg (- arg))
  415.                  (while (> arg 0)
  416.                    (if (not (equal address (logior address 7)))
  417.                    (if (> address hexl-max-address)
  418.                        (progn
  419.                      (message "End of buffer.")
  420.                      (setq address hexl-max-address))
  421.                      (setq address (logior address 7)))
  422.                  (if (> address hexl-max-address)
  423.                      (progn
  424.                        (message "End of buffer.")
  425.                        (setq address hexl-max-address))
  426.                    (setq address (+ address 8))))
  427.                    (setq arg (1- arg)))
  428.                  (if (> address hexl-max-address)
  429.                  (progn
  430.                    (message "End of buffer.")
  431.                    (setq address hexl-max-address))
  432.                    (setq address (logior address 7))))
  433.              (while (> arg 0)
  434.                (if (not (equal address (logand address -8)))
  435.                    (setq address (logand address -8))
  436.                  (if (not (equal address 0))
  437.                  (setq address (- address 8))
  438.                    (message "Beginning of buffer.")))
  439.                (setq arg (1- arg))))
  440.                address)))
  441.  
  442. (defun hexl-forward-word (arg)
  443.   "Move right ARG words (left if ARG negative) in hexl-mode."
  444.   (interactive "p")
  445.   (hexl-backward-word (- arg)))
  446.  
  447. (defun hexl-previous-line (arg)
  448.   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
  449. If there is byte at the target address move to the last byte in that line."
  450.   (interactive "p")
  451.   (hexl-next-line (- arg)))
  452.  
  453. (defun hexl-next-line (arg)
  454.   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
  455. If there is no byte at the target address move to the last byte in that line."
  456.   (interactive "p")
  457.   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
  458.                (if (and (< arg 0) (< address 0))
  459.                 (progn (message "Out of hexl region.")
  460.                        (setq address
  461.                          (% (hexl-current-address) 16)))
  462.              (if (and (> address hexl-max-address)
  463.                   (< (% hexl-max-address 16) (% address 16)))
  464.                  (setq address hexl-max-address)
  465.                (if (> address hexl-max-address)
  466.                    (progn (message "Out of hexl region.")
  467.                       (setq
  468.                        address
  469.                        (+ (logand hexl-max-address -16)
  470.                       (% (hexl-current-address) 16)))))))
  471.                address)))
  472.  
  473. (defun hexl-beginning-of-buffer (arg)
  474.   "Move to the beginning of the hexl buffer.
  475. Leaves `hexl-mark' at previous position.
  476. With prefix arg N, puts point N bytes of the way from the true beginning."
  477.   (interactive "p")
  478.   (push-mark (point))
  479.   (hexl-goto-address (+ 0 (1- arg))))
  480.  
  481. (defun hexl-end-of-buffer (arg)
  482.   "Go to `hexl-max-address' minus ARG."
  483.   (interactive "p")
  484.   (push-mark (point))
  485.   (hexl-goto-address (- hexl-max-address (1- arg))))
  486.  
  487. (defun hexl-beginning-of-line ()
  488.   "Goto beginning of line in hexl mode."
  489.   (interactive)
  490.   (goto-char (+ (* (/ (point) 68) 68) 11)))
  491.  
  492. (defun hexl-end-of-line ()
  493.   "Goto end of line in hexl mode."
  494.   (interactive)
  495.   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
  496.                (if (> address hexl-max-address)
  497.                (setq address hexl-max-address))
  498.                address)))
  499.  
  500. (defun hexl-scroll-down (arg)
  501.   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
  502.   (interactive "P")
  503.   (if (null arg)
  504.       (setq arg (1- (window-height)))
  505.     (setq arg (prefix-numeric-value arg)))
  506.   (hexl-scroll-up (- arg)))
  507.  
  508. (defun hexl-scroll-up (arg)
  509.   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
  510.   (interactive "P")
  511.   (if (null arg)
  512.       (setq arg (1- (window-height)))
  513.     (setq arg (prefix-numeric-value arg)))
  514.   (let ((movement (* arg 16))
  515.     (address (hexl-current-address)))
  516.     (if (or (> (+ address movement) hexl-max-address)
  517.         (< (+ address movement) 0))
  518.     (message "Out of hexl region.")
  519.       (hexl-goto-address (+ address movement))
  520.       (recenter 0))))
  521.  
  522. (defun hexl-beginning-of-1k-page ()
  523.   "Go to beginning of 1k boundary."
  524.   (interactive)
  525.   (hexl-goto-address (logand (hexl-current-address) -1024)))
  526.  
  527. (defun hexl-end-of-1k-page ()
  528.   "Go to end of 1k boundary."
  529.   (interactive)
  530.   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
  531.                (if (> address hexl-max-address)
  532.                (setq address hexl-max-address))
  533.                address)))
  534.  
  535. (defun hexl-beginning-of-512b-page ()
  536.   "Go to beginning of 512 byte boundary."
  537.   (interactive)
  538.   (hexl-goto-address (logand (hexl-current-address) -512)))
  539.  
  540. (defun hexl-end-of-512b-page ()
  541.   "Go to end of 512 byte boundary."
  542.   (interactive)
  543.   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
  544.                (if (> address hexl-max-address)
  545.                (setq address hexl-max-address))
  546.                address)))
  547.  
  548. (defun hexl-quoted-insert (arg)
  549.   "Read next input character and insert it.
  550. Useful for inserting control characters.
  551. You may also type up to 3 octal digits, to insert a character with that code"
  552.   (interactive "p")
  553.   (hexl-insert-char (read-quoted-char) arg))
  554.  
  555. ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
  556.  
  557. ;;;###autoload
  558. (defun hexlify-buffer ()
  559.   "Convert a binary buffer to hexl format.
  560. This discards the buffer's undo information."
  561.   (interactive)
  562.   (and buffer-undo-list
  563.        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
  564.        (error "Aborted")))
  565.   (setq buffer-undo-list nil)
  566.   (let ((binary-process-output nil) ; for Ms-Dos
  567.     (binary-process-input t)
  568.     (buffer-undo-list t))
  569.     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
  570.  
  571. (defun dehexlify-buffer ()
  572.   "Convert a hexl format buffer to binary.
  573. This discards the buffer's undo information."
  574.   (interactive)
  575.   (and buffer-undo-list
  576.        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
  577.        (error "Aborted")))
  578.   (setq buffer-undo-list nil)
  579.   (let ((binary-process-output t) ; for Ms-Dos
  580.     (binary-process-input nil)
  581.     (buffer-undo-list t))
  582.     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
  583.  
  584. (defun hexl-char-after-point ()
  585.   "Return char for ASCII hex digits at point."
  586.   (hexl-htoi (char-after (point))
  587.          (char-after (1+ (point)))))
  588.  
  589. (defun hexl-htoi (lh rh)
  590.   "Hex (char) LH (char) RH to integer."
  591.     (+ (* (hexl-hex-char-to-integer lh) 16)
  592.        (hexl-hex-char-to-integer rh)))
  593.  
  594. (defun hexl-hex-char-to-integer (character)
  595.   "Take a char and return its value as if it was a hex digit."
  596.   (if (and (>= character ?0) (<= character ?9))
  597.       (- character ?0)
  598.     (let ((ch (logior character 32)))
  599.       (if (and (>= ch ?a) (<= ch ?f))
  600.       (- ch (- ?a 10))
  601.     (error "Invalid hex digit `%c'." ch)))))
  602.  
  603. (defun hexl-oct-char-to-integer (character)
  604.   "Take a char and return its value as if it was a octal digit."
  605.   (if (and (>= character ?0) (<= character ?7))
  606.       (- character ?0)
  607.     (error "Invalid octal digit `%c'." character)))
  608.  
  609. (defun hexl-printable-character (ch)
  610.   "Return a displayable string for character CH."
  611.   (format "%c" (if hexl-iso
  612.            (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
  613.                46
  614.              ch)
  615.          (if (or (< ch 32) (>= ch 127))
  616.              46
  617.            ch))))
  618.  
  619. (defun hexl-self-insert-command (arg)
  620.   "Insert this character."
  621.   (interactive "p")
  622.   (hexl-insert-char last-command-char arg))
  623.  
  624. (defun hexl-insert-char (ch num)
  625.   "Insert a character in a hexl buffer."
  626.   (let ((address (hexl-current-address t)))
  627.     (while (> num 0)
  628.       (let ((hex-position
  629.          (+ (* (/ address 16) 68)
  630.         11
  631.         (* 2 (% address 16))
  632.         (/ (% address 16) 2)))
  633.         (ascii-position
  634.          (+ (* (/ address 16) 68) 52 (% address 16)))
  635.         at-ascii-position)
  636.     (if (= (point) ascii-position)
  637.         (setq at-ascii-position t))
  638.     (goto-char hex-position)
  639.     (delete-char 2)
  640.     (insert (format "%02x" ch))
  641.     (goto-char ascii-position)
  642.     (delete-char 1)
  643.     (insert (hexl-printable-character ch))
  644.     (or (eq address hexl-max-address)
  645.         (setq address (1+ address)))
  646.     (hexl-goto-address address)
  647.     (if at-ascii-position
  648.         (progn
  649.           (beginning-of-line)
  650.           (forward-char 51)
  651.           (forward-char (% address 16)))))
  652.       (setq num (1- num)))))
  653.  
  654. ;; hex conversion
  655.  
  656. (defun hexl-insert-hex-char (arg)
  657.   "Insert a ASCII char ARG times at point for a given hexadecimal number."
  658.   (interactive "p")
  659.   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
  660.     (if (or (> num 255) (< num 0))
  661.     (error "Hex number out of range.")
  662.       (hexl-insert-char num arg))))
  663.  
  664. (defun hexl-insert-decimal-char (arg)
  665.   "Insert a ASCII char ARG times at point for a given decimal number."
  666.   (interactive "p")
  667.   (let ((num (string-to-int (read-string "Decimal Number: "))))
  668.     (if (or (> num 255) (< num 0))
  669.     (error "Decimal number out of range.")
  670.       (hexl-insert-char num arg))))
  671.  
  672. (defun hexl-insert-octal-char (arg)
  673.   "Insert a ASCII char ARG times at point for a given octal number."
  674.   (interactive "p")
  675.   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
  676.     (if (or (> num 255) (< num 0))
  677.     (error "Decimal number out of range.")
  678.       (hexl-insert-char num arg))))
  679.  
  680. ;; startup stuff.
  681.  
  682. (if hexl-mode-map
  683.     nil
  684.   (setq hexl-mode-map (make-sparse-keymap))
  685.  
  686.   (define-key hexl-mode-map [left] 'hexl-backward-char)
  687.   (define-key hexl-mode-map [right] 'hexl-forward-char)
  688.   (define-key hexl-mode-map [up] 'hexl-previous-line)
  689.   (define-key hexl-mode-map [down] 'hexl-next-line)
  690.   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
  691.   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
  692.   (define-key hexl-mode-map [next] 'hexl-scroll-up)
  693.   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
  694.   (define-key hexl-mode-map [home] 'hexl-beginning-of-buffer)
  695.   (define-key hexl-mode-map [deletechar] 'undefined)
  696.   (define-key hexl-mode-map [deleteline] 'undefined)
  697.   (define-key hexl-mode-map [insertline] 'undefined)
  698.   (define-key hexl-mode-map [S-delete] 'undefined)
  699.   (define-key hexl-mode-map "\177" 'undefined)
  700.  
  701.   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
  702.   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
  703.   (define-key hexl-mode-map "\C-d" 'undefined)
  704.   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
  705.   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
  706.  
  707.   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
  708.       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
  709.  
  710.   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
  711.   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
  712.   (define-key hexl-mode-map "\C-k" 'undefined)
  713.   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
  714.   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
  715.   (define-key hexl-mode-map "\C-o" 'undefined)
  716.   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
  717.   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
  718.   (define-key hexl-mode-map "\C-t" 'undefined)
  719.   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
  720.   (define-key hexl-mode-map "\C-w" 'undefined)
  721.   (define-key hexl-mode-map "\C-y" 'undefined)
  722.  
  723.   (let ((ch 32))
  724.     (while (< ch 127)
  725.       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
  726.       (setq ch (1+ ch))))
  727.  
  728.   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
  729.   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
  730.   (define-key hexl-mode-map "\e\C-c" 'undefined)
  731.   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
  732.   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
  733.   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
  734.   (define-key hexl-mode-map "\e\C-g" 'undefined)
  735.   (define-key hexl-mode-map "\e\C-h" 'undefined)
  736.   (define-key hexl-mode-map "\e\C-i" 'undefined)
  737.   (define-key hexl-mode-map "\e\C-j" 'undefined)
  738.   (define-key hexl-mode-map "\e\C-k" 'undefined)
  739.   (define-key hexl-mode-map "\e\C-l" 'undefined)
  740.   (define-key hexl-mode-map "\e\C-m" 'undefined)
  741.   (define-key hexl-mode-map "\e\C-n" 'undefined)
  742.   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
  743.   (define-key hexl-mode-map "\e\C-p" 'undefined)
  744.   (define-key hexl-mode-map "\e\C-q" 'undefined)
  745.   (define-key hexl-mode-map "\e\C-r" 'undefined)
  746.   (define-key hexl-mode-map "\e\C-s" 'undefined)
  747.   (define-key hexl-mode-map "\e\C-t" 'undefined)
  748.   (define-key hexl-mode-map "\e\C-u" 'undefined)
  749.  
  750.   (define-key hexl-mode-map "\e\C-w" 'undefined)
  751.   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
  752.   (define-key hexl-mode-map "\e\C-y" 'undefined)
  753.  
  754.   (define-key hexl-mode-map "\ea" 'undefined)
  755.   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
  756.   (define-key hexl-mode-map "\ec" 'undefined)
  757.   (define-key hexl-mode-map "\ed" 'undefined)
  758.   (define-key hexl-mode-map "\ee" 'undefined)
  759.   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
  760.   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
  761.   (define-key hexl-mode-map "\eh" 'undefined)
  762.   (define-key hexl-mode-map "\ei" 'undefined)
  763.   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
  764.   (define-key hexl-mode-map "\ek" 'undefined)
  765.   (define-key hexl-mode-map "\el" 'undefined)
  766.   (define-key hexl-mode-map "\em" 'undefined)
  767.   (define-key hexl-mode-map "\en" 'undefined)
  768.   (define-key hexl-mode-map "\eo" 'undefined)
  769.   (define-key hexl-mode-map "\ep" 'undefined)
  770.   (define-key hexl-mode-map "\eq" 'undefined)
  771.   (define-key hexl-mode-map "\er" 'undefined)
  772.   (define-key hexl-mode-map "\es" 'undefined)
  773.   (define-key hexl-mode-map "\et" 'undefined)
  774.   (define-key hexl-mode-map "\eu" 'undefined)
  775.   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
  776.   (define-key hexl-mode-map "\ey" 'undefined)
  777.   (define-key hexl-mode-map "\ez" 'undefined)
  778.   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
  779.   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
  780.  
  781.   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
  782.  
  783.   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
  784.   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
  785.   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
  786.   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
  787.   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
  788.  
  789. ;;; hexl.el ends here
  790.